마인크래프트 자바에디션 1.21.5 - Text 구성요소 업데이트 정리

해당 글은 마인크래프트 업데이트 기사와 마인크래프트 1.21.5 위키 항목을 바탕으로 작성되었습니다.

---

Text 구성요소

JSON 포맷 변경

• 이제 Text 구성요소가 JSON 문자열 형태로 감싸져 저장되지 않고, 바로 상위 구조에 인라인(inline) 형식으로 저장됩니다.
• "text":"내용" -> text:"내용" 형태가 됩니다. 
  • 예시:
    • 기존: minecraft:custom_name="{\"text\":\"아이템 이름\"}"
    • 변경 후: minecraft:custom_name={text:'아이템 이름'}
      
    • 기존: minecraft:lore=["{\"text\":\"이것은 전설의 아이템이다\"}"]
    • 변경 후: minecraft:lore=[{text:'이것은 전설의 아이템이다'}]
• 만약 기존의 작성방식으로 적을 경우 그대로 들어갑니다.

명령어 적용 방식 변경

• /tellraw, /title 등 Text 구성요소를 사용하는 명령어도 동일하게 변경되었습니다.
  • 예시:
    • 기존: /tellraw @a {"text":"안녕하세요"}
    • 변경 후: /tellraw @a {text:'안녕하세요'}
      
      
    • 기존: /title @a title {"text":"게임 시작!"}
    • 변경 후: /title @a title {text:'게임 시작!'}

NBT 내 Boolean과 Integer 타입

• NBT 내에 포함된 Text 구성요소에서는 boolean 타입과 integer 타입의 구분이 사라졌습니다.
• 번역 인수에 boolean 값을 전달하려면, 반드시 문자열 형태로 사용해야 합니다.
  • 예시 : /tellraw @a {translate:"advMode.setCommand.success"}

• 번역 인수에 %s가 있다면 with를 사용하여 값을 전달할 수 있습니다.
  • /tellraw @a {translate:"advMode.setCommand.success", with:["test"]}

• 만약 문자열이 아니라 boolean 값을 그대로 넣어주면 int로 넘어가게 됩니다.
  • /tellraw @a {translate:"advMode.setCommand.success", with:[false]}

• 그런데 1.21.4에서도 true, false로 넣으면 자동으로 변환되어 1, 0으로 나오기에 별 차이는 없습니다.

 

NBT Text 구성요소 파싱 방식

• NBT 타입을 가진 Text 구성요소에서 interpret 값이 true일 경우, 구성요소는 문자열로 변환 후 JSON으로 파싱되는 대신 주어진 NBT 데이터를 직접 파싱합니다.
  • 예시: /tellraw @a {nbt:'data', entity:'@n[type=cow]', interpret:true}
    • 밑의 사진에서 첫번째 출력은 interpret이 true일때, 두번째 출력은 false 일 때 입니다.

---

Hover Events

• hoverEvent가 hover_event로 이름 변경되었습니다.
• 렌더링된 Text 구성요소에서 파싱되었던 기존의 옛날 value 필드가 더 이상 지원되지 않습니다.

show_text 액션

• contents 필드가 value로 변경되었습니다.
  • 예시:
    • 기존: {action:'show_text',contents:'안녕하세요'}
    • 변경 후: {action:'show_text',value:'안녕하세요'}
      • /tellraw @a {text:'test', hover_event:{action:'show_text',value:'안녕하세요'}}

show_item 액션

• contents 필드가 인라인 처리되어 직접 필드에 포함됩니다.
  • 예시:
    • 기존: {action:'show_item',contents:{id:'minecraft:stick',count:2}}
    • 변경 후: {action:'show_item',id:'minecraft:stick',count:2}
      
      • /tellraw @a {text:'test', hover_event:{action:'show_item',id:'minecraft:stick',count:2}}
        
        
    • 기존: {action:'show_item',contents:'minecraft:diamond_sword'}
    • 변경 후: {action:'show_item',id:'minecraft:diamond_sword'}
      • /tellraw @a {text:'test', hover_event:{action:'show_item',id:'minecraft:diamond_sword'}}

show_entity 액션

• contents 필드가 인라인 처리되어 직접 필드에 포함됩니다.
• 기존의 id 필드가 uuid로, 기존의 type 필드가 id로 변경되었습니다.
  • 예시:
    • 기존: {action:'show_entity',contents:{id:[I;0,0,0,0],type:'minecraft:pig'}}
    • 변경 후: {action:'show_entity',uuid:[I;0,0,0,0],id:'minecraft:pig'}
      • /tellraw @a {text:'test', hover_event:{action:'show_entity',uuid:[I;0,0,0,0],id:'minecraft:pig'}}
        
        
    • 또다른 예시 : {action:'show_entity',uuid:[I;123,456,789,0],id:'minecraft:zombie'}
      • /tellraw @a {text:'test', hover_event:{action:'show_entity',uuid:[I;123,456,789,0],id:'minecraft:zombie'}}

---

Click Events

• clickEvent가 click_event로 이름 변경되었습니다.

open_url 액션

• 기존의 value 필드가 url로 변경되었습니다.
• 반드시 유효한 URI(https:// 또는 http://)가 포함되어야 합니다.
  • 예시:
    • 기존: {action:'open_url',value:'https://potangaming.tistory.com/318'}
    • 변경 후: {action:'open_url',url:'https://potangaming.tistory.com/318'}
      • /tellraw @a {text:'test', click_event:{action:'open_url',url:'https://potangaming.tistory.com/318'}}

run_command 액션

• 기존의 value 필드가 command로 변경되었습니다.
• 허용되지 않는 문자를 포함한 명령어는 더 이상 구문분석되지 않습니다.
  • 잘못된 명령어를 넣어서 눌렀을 때

• / 접두사가 선택사항이 되었습니다.
  • 예시:
    • 기존: {action:'run_command',value:'/tp @e @s'}
    • 변경 후: {action:'run_command',command:'/tp @e @s'}
      
      • /tellraw @a {text:'누르면 큰일남', click_event:{action:'run_command',command:'/tp @e @s'}}
    • 또 다른 예시 : {action:'run_command',command:'give @p diamond 1'}
      • /tellraw @a {text:'누르면 큰일남', click_event:{action:'run_command',command:'give @p diamond 1'}}

suggest_command 액션

• 기존의 value 필드가 command로 변경되었습니다.
• 허용되지 않는 문자를 포함한 명령어는 더 이상 구문 분석되지 않습니다.
  • 예시:
    • 기존: {action:'suggest_command',value:'/help'}
    • 변경 후: {action:'suggest_command',command:'/help'}
      • /tellraw @a {text:'가이드', click_event:{action:'suggest_command',command:'/help'}}
    • 또 다른 예시: {action:'suggest_command',command:'/time set day'}
      • /tellraw @a {text:'밤이 싫어요', click_event:{action:'suggest_command',command:'/time set day'}}

change_page 액션

• 기존의 value 필드가 page로 변경되었습니다.
• 페이지 값은 반드시 양의 정수여야 합니다.
  • 예시:
    • 기존: {action:'change_page',value:'1'}
    • 변경 후: {action:'change_page',page:1}

copy_to_clipboard 액션

• 기존 형식에서 변경된 점이 없습니다..
  • 예시:
    • {action:'copy_to_clipboard',value:'클립보드에 복사될 내용'}
      • /tellraw @a {text:'눌러보세요', click_event:{action:'copy_to_clipboard',value:'포탄 블로그는 세계 최고의 뭐시기'}}

---